********************************************************************************
*                                                                             							        
* Washington State CGE Model                                                                                                            
* 18 AUGUST 2016                                                              
* Timothy P. Nadreau                                                          
* Based on a model developed by Hans Lofgren                                   
*                                                                              
********************************************************************************

$SETGLOBAL PROGPATH C:\Users\Tim Nadreau\Desktop\WSU Classes\EconS_587_Regional\WA-ID_CGE\

********************************************************************************
*                                                                              
* If the global variable LBR is set to NO, the employment data from IMPLAN will
* not be used. QFO will be set to the numbers in the SAM.                      
* If LBR is set to YES, the employment data from IMPLAY will be used. QFO will 
* be set to the employment data extracted from IMPLAN. In this case, QF        
* represents actual number of jobs.                                            
*                                                                              
********************************************************************************

$SETGLOBAL LBR NO

* The following line assumes that the input file containing the SAM data is
* named SAM.GMS

$INCLUDE "%PROGPATH%SAM.gms"

$ONEMPTY

SET NAG(A)       non-ag activities
    /
    FOREST-A       Forestry
    CONST-A        Construction
    UTIL-A         Utilities
    Fossil-A       Fossil-Fuel
    TRAD-A         Wholesale and retail trade
    MIN-A          Mining and quarrying
    FOOD-A         Processed food
    MAN-A          Manufacturing
    SER-A          Services
    MISC-A         Miscellaneous
    /
;

SET NSER(C)       non-Services activities
    /
    AGR-C          Agriculture
    FOREST-C       Forestry
    CONST-C        Construction
    UTIL-C         Utilities
    Fossil-C       Fossil-Fuel
    TRAD-C         Wholesale and retail trade
    MIN-C          Mining and quarrying
    FOOD-C         Processed food
    MAN-C          Manufacturing
    /
;

SET FF(F)   Production Factors
   /
   LAB            Employee Compensation
   CAP            Proprietary Income
   /
;

*new sector for reporting the IBT in the report
SET VA(F)   Production Factors
   /
   INDT           Indirect Business Taxes
   /
;

SET H(I)   Households
   /
   HHD1
   HHD2
   HHD3
   HHD4
   HHD5
   HHD6
   HHD7
   HHD8
   HHD9
   /
;

SET G(I) Government units
   /
   FGOVND     Federal Govt Non-Defense
   FGOVD      Federal Govt Defense
   FGOVI      Federal Govt Investment
   SGOVNE     State Local Govt Non-Education
   SGOVE      State Local Govt Education
   SGOVI      State Local Govt Investment
   /
;

SET FG(G) Federal government units
   /
   FGOVND     Federal Govt Non-Defense
   FGOVD      Federal Govt Defense
   FGOVI      Federal GOvt Investment
   /
;

SET SG(G) State government units
   /
   SGOVNE     State Local Govt Non-Education
   SGOVE      State Local Govt Education
   SGOVI      State Local Govt Investment
   /
;


SET HG(I) Households and Government units;

HG(I) = H(I) + G(I);

ALIAS (FF,FFF),(C,CC),(H,HH),(G,GG),(FG,FGG),(SG,SGG);

* Parameters set by user
PARAMETERS
      CAPCLOS           Capital closure
      LABCLOS           Labor closure
      SICLOS            Savings investment closure
      ROWCLOS           Foreign savings closure
      RUSCLOS           RUS savings closure

      xed(C,T)          Elasticity of demand for world export function
      esubp(A)          Elasticity of substitution for production
      esubd(C)          Elasticity of substitution (armington) between regional output and imports
      esubs(C)          Elasticity of substitution (transformation) between domestic (regional) and foreign demand
      esube(C)          Elasticity of substitution (transformation) between row and rus for exports
      esubm(C)          Elasticity of substitution (armington) between row imports and rus  imports
      ine(C,H)          Income elasticity
      frisch(C)         Consumption flexibility--determines minimum subsistence level of consumption -1 imples zero minimum
      efac(FF)          Demand elasticity for capital and labor
      trans(H)          Household transfer from the I-732
;

* Set closure options here
      CAPCLOS = 2;
*         if CAPCLOS = 1, capital is mobile and supply is fixed
*         if CAPCLOS = 2, capital is mobile and supply is variable
*         if CAPCLOS = 3, capital is activity specific and fixed

      LABCLOS = 3;
*         if LABCLOS = 1, labor is mobile and supply is fixed
*         if LABCLOS = 2, labor is mobile and supply is variable
*         if LABCLOS = 3, labor is mobile. Unemployment is possible.

      SICLOS = 2;
*         if SICLOS = 1, savings is investment driven
*         if SICLOS = 2, investment is savings driven
*         if SICLOS = 3, CPI changes

      ROWCLOS = 3;
*         if ROWCLOS = 1, exchange rate is variable
*         if ROWCLOS = 2, foreign savings (export - FSAVX) is variable
*         if ROWCLOS = 3, foreign savings (import - FSAVM) is variable

      RUSCLOS = 1;
*         if RUSCLOS = 1, RUS exchange rate is variable
*         if RUSCLOS = 2, RUS savings (export - DSAVX) is variable
*         if RUSCLOS = 3, RUS savings (import - DSAVM) is variable

* Set parameters here
      xed(C,T)   = -50;
      esubp(A)   = .99;
      esubd(C)   = 2;
      esubs(C)   = 2;
      esube(C)   = 2;
      esubm(C)   = 2;
      ine(C,H)   = 1;
      frisch(C)  = -1;
      efac(FF)   = 0.8;
      trans(H)   = 0;


SCALAR sgovbal State government budget balance;

PARAMETERS
      PMO(C)         Initial import price (domestic currency)
      XRO(T)         Initial exchange rate
      PEO(C)         Initial export price (domestic currency)
      PQO(C)         Initial composite commodity price
      PDO(C)         Initial domestic price of domestic output
      QQO(C)         Initial quantity supplied to domestic commodity demanders
      QMO(C)         Initial quantity of imports
      QDO(C)         Initial quantity of domestic output sold domestically
      PXO(C)         Initial producer price
      QXO(C)         Initial quantity of domestic output
      QEO(C)         Initial quantity of exports
      PAO(A)         Initial activity price
      PVAO(A)        Initial value added price
      QAO(A)         Initial activity level
      QFO(FF,A)      Initial quantity demanded of factor FF by activity A
      QINTO(C,A)     Initial quantity of intermeditate use of commodity C by activity A
      WFO(FF)        Initial average wage or rental rate of factor FF
      YFO(I,FF)      Initial transfer of income to institution I from factor FF
      YHO(H)         Initial gross household income
      NYHO(H)        Initial net household income
      QHO(C,H)       Initial household comsumption
      QINVO(C)       Initial investment demand
      QIINVO(I)      Initial institutional investment
      YFGO           Initial federal government revenue
      EFGO           Initial federal government expenditures
      YSGO           Initial state government revenue
      ESGO           Initial state government expenditures
      QFSO(FF)       Initial factor supply
      FSAVXO         Initial exports foreign savings
      DSAVXO         Initial exports RUS savings
      FSAVMO         Initial imports foreign savings
      DSAVMO         Initial imports RUS savings
      WFDISTO(FF,A)  Initial distortion factor for factor FF in activity A
      INDTO(G)       Initial indirect taxes
      IMAKEQO(I,C)   Initial institutional make matrix (quantity)
      QMRO(T,C)      Initial regional imports
      PMRO(T,C)      Initial regional import price
      QERO(C,T)      Initial regional exports
      PERO(C,T)      Initial regional export price
      PWEO(C,T)      Initial world export price
      IADJO          Initial investment adjustment factor
      SADJO          Initial savings adjustment factor
      SGADJO         Initial state government adjustment factor for quantity purchased
      SHIFTFFO(FF)   Initial Factor supply equation shift variable
      QIBTO(VA,A)    Initial quantity of set VA by activity A
;


PARAMETERS
      theta(A,C)        Yield of output C per unit of activity A
      ica(C,A)          Quantity of C as intermediate input per unit of activity A
      ivaa(VA,A)        Quantity of VA as intermediate input per unit of activity A

      ad(A)             Production shift parameter
      del(F,A)          Production function share parameter
      rho(A)            CES production function exponent

      adel(C)           Armington commodity composite share parameter for production
      aq(C)             Armington commodity composite shift parameter
      arho(C)           Armington commodity composite exponent

      sdel(C)           Armington CET composite share parameter for domestic sales
      srho(C)           Armington CET composite exponent
      as(C)             Armington CET composite shift parameter

      edel(C)           Armington composite share parameter foreign exports
      erho(C)           Armington composite exponent for exports
      ae(C)             Armington composite shift parameter for exports

      mdel(C)           Armington composite share parameter foreign imports
      mrho(C)           Armington composite exponent for imports
      am(C)             Armington composite shift parameter for imports

      tc(H,C)           Consumption tax (only paid by households)
      tq(A,C)           Sales Tax activity A pays for Commodity C
      tqs(C)            Sales tax on services not previously taxed
      tm(T,C)           Import taxes
      te(C,T)           Export tax rate
      tb(A)             Indirect business tax rate
      mps(H)            Marginal propensity to save
      ty(G,H)           Rate of household income tax
      trh(H,HH)         Interhousehold transfers
      pwm(T,C)          ROW and RUS import price
      cwts(C)           weight of commodity C in the cpi
      CPIO              initial consumer price index
      wfa(FF,A)         wage for factor FF in activity A
      xshift(C,T)       Shift parameter for world export demand function
      lambda(C,H)       Subsistance level parameter
      beta(C,H)         Marginal budget share parameter
      engelwt(H)        Engel aggregation weight
      qg(C,G)           Government consumption
      shry(I,FF)        Instutional share of factor income
      tbshr(G)          Government unit share of indirect business taxes
;

      tc(H,C)    = 0;
      tq(A,C)    = 0;
      tqs(C)     = 0;
      tm(T,C)    = 0;
      te(C,T)    = 0;

      PMO(C) = 1;
      XRO(T) = 1;
      PWEO(C,T) = 1;
      PEO(C) = 1;
      PQO(C) = 1+tqs(C);
      PDO(C) = PQO(C);
      PXO(C) = 1;
      PAO(A) = 1;
      QMO(C)     = SUM(T,SAM(T,C))/PMO(C);
      QXO(C)     = (SUM(A,SAM(A,C))+ SUM(I,SAM(I,C)))/PXO(C);
      QDO(C)     = (SUM(A,SAM(A,C)) + SUM(I,SAM(I,C)) - SUM(T,SAM(C,T)))/PDO(C);
      QQO(C)     = (SAM('TOTAL',C) - SUM(T,SAM(C,T)))/PQO(C);
      QEO(C)     = SUM(T,SAM(C,T))/PEO(C);
      QAO(A)     = SAM('TOTAL',A)/PAO(A);
      QFO('CAP',A)  = SAM('CAP',A);
$IF %LBR% == "NO" $GOTO LW1
      QFO('LAB',A)  = EMPLOY(A);
$GOTO LW2
$LABEL LW1
      QFO('LAB',A)  = SAM('LAB',A);
$LABEL LW2
      WFO(FF) =    SUM(A, SAM(FF,A))/SUM(A, QFO(FF,A));
      QINTO(C,A) = SAM(C,A)/PQO(C);
      YFO(I,FF)  = SAM(I,FF);
      PVAO(A)    = SUM(FF,SAM(FF,A))/(SAM('TOTAL',A)/PAO(A));
      YHO(H)     = SUM(FF,SAM(H,FF)) + SUM(I,SAM(H,I)) + SUM(T,SAM(H,T)) + SUM(C,PXO(C)*SAM(H,C));
      NYHO(H)    = SUM(C,SAM(C,H));
      QHO(C,H)   = SAM(C,H)/(PQO(C)*(1+(sum(HH,tc(H,C))/9)));
      QINVO(C)   = SAM(C,'INV')/PQO(C);
      QIINVO(I) = SAM(I,'INV');
      QIBTO('INDT',A)= SAM('INDT',A);

      YFGO       = SUM(FG,SAM(FG,'TOTAL'));
      EFGO       = SUM(FG,SAM('TOTAL',FG)) - SUM(FG,SAM('INV',FG));

*      YSGO       = SUM((H,SG),ty(SG,H)*YH(H)) + CPI*SUM((T,SG),SAM(SG,T)) + CPI*SUM((SG,FG),SAM(SG,FG))
*                         + SUM((C,SG),PX(C)*IMAKEQ(SG,C)) + SUM(SG,QIINV(SG))
*                         + SUM((SG,FF),YF(SG,FF)) + SUM(SG,INDT(SG))
*                         + SUM(C,PD(C)*QD(C)*tqs(C))
*                         + SUM(C,(PM(C)*QM(C)$CM(C) + PD(C)*QD(C))*(sum(A,tq(A,C))/11))
*                         + SUM((H,C),PQ(C)*tc(H,C)*QH(C,H));

      YSGO       = SUM(SG,SAM(SG,'TOTAL'))-SUM((SG,SGG),SAM(SGG,SG));
      ESGO       = SUM(SG,SAM('TOTAL',SG)) - SUM(SG,SAM('INV',SG))-SUM((SG,SGG),SAM(SGG,SG));
      QFSO(FF)   = SUM(A,SAM(FF,A)/WFO(FF));
      FSAVXO      = SAM('INV','FT')/XRO('FT');
      DSAVXO      = SAM('INV','DT')/XRO('DT');
      FSAVMO      = SAM('FT','INV')/XRO('FT');
      DSAVMO      = SAM('DT','INV')/XRO('DT');
      wfa(FF,A)     = SAM(FF,A)/QFO(FF,A);
      WFDISTO(FF,A) = wfa(FF,A) / WFO(FF);

      INDTO(G)   = SAM(G,'INDT');
      IMAKEQO(I,C) = SAM(I,C)/PXO(C);
      IADJO       = 1;
      SADJO       = 1;
      SGADJO      = 1;

      ty(G,H)    = SAM(G,H)/SAM('TOTAL',H);
      tb(A)      = (SAM('INDT',A))/SAM('TOTAL',A);
      pwm(T,C)   = 1;
      trh(H,HH)  = SAM(H,HH) /((1-SUM(G,ty(G,HH)))*SAM('TOTAL',HH));
      mps(H)     = SAM('INV',H)/((1-SUM(G,ty(G,H)))*SAM('TOTAL',H));
      qg(C,G)    = SAM(C,G)/PQO(C);

      PMRO(T,C) = pwm(T,C)*(1+tm(T,C))*XRO(T);
      QMRO(T,C)  = SAM(T,C)/PMRO(T,C);
      PERO(C,T) = PWEO(C,T)*XRO(T)*(1-te(C,T));
      QERO(C,T)  = SAM(C,T)/PERO(C,T);

      xshift(C,T) = QERO(C,T)/(PWEO(C,T)**xed(C,T));
      SHIFTFFO(FF) = QFSO(FF)/(WFO(FF)**efac(FF));

SET CM(C),CE(C),CNM(C),CNE(C);
SET CM1(C),CE1(C),CM2(C),CE2(C);

      CM(C) = YES$QMO(C);
      CE(C) = YES$QEO(C);
      CNM(C) = YES$(QMO(C) = 0);
      CNE(C) = YES$(QEO(C) = 0);
      CM1(C) = YES$((QMRO('FT',C) AND QMRO('DT',C) = 0) OR (QMRO('FT',C) = 0 AND QMRO('DT',C)));
      CE1(C) = YES$((QERO(C,'FT') AND QERO(C,'DT') = 0) OR (QERO(C,'FT') = 0 AND QERO(C,'DT')));
      CM2(C) = YES$(QMRO('FT',C) AND QMRO('DT',C));
      CE2(C) = YES$(QERO(C,'FT') AND QERO(C,'DT'));

      theta(A,C) = (SAM(A,C)/PXO(C)) / QAO(A);
      ica(C,A)   = QINTO(C,A)/QAO(A);
      ivaa(VA,A)   = QIBTO(VA,A)/QAO(A);

      rho(A)=1/esubp(A)-1;

      del(FF,A) = (WFDISTO(FF,A)*WFO(FF)*QFO(FF,A)**(rho(A)+1))/SUM(FFF,WFDISTO(FFF,A)*WFO(FFF)*QFO(FFF,A)**(rho(A)+1));
      ad(A) = (QAO(A)*(1-tb(A)-SUM(C,ica(C,A))))/(SUM(FF, del(FF,A)*QFO(FF,A)**(-rho(A))))**(-1/rho(A));

      arho(CM)=1/esubd(CM)-1;
      adel(CM)=(QMO(CM)**(1+arho(CM)))*PMO(CM)
           /(QMO(CM)**(1+arho(CM))*PMO(CM) + QDO(CM)**(1+arho(CM))*PDO(CM));
      aq(CM) =  QQO(CM)/(
           adel(CM)*QMO(CM)**(-arho(CM))+(1-adel(CM))*QDO(CM)**(-arho(CM)))
          **(-1/arho(CM));

      srho(CE)=1/esubs(CE)+1;



      sdel(CE)=(QEO(CE)**(1-srho(CE)))*PEO(CE)
           /(QDO(CE)**(1-srho(CE))*PDO(CE)+QEO(CE)**(1-srho(CE))*PEO(CE));
      as(CE) = QXO(CE)/(sdel(CE)*QEO(CE)**(srho(CE))+
              (1-sdel(CE))*QDO(CE)**(srho(CE)))
                 **(1/srho(CE));

      erho(CE2) = 1/esube(CE2) + 1;
      edel(CE2)=(QERO(CE2,'FT')**(1-erho(CE2)))*PERO(CE2,'FT')
           /(QERO(CE2,'FT')**(1-erho(CE2))*PERO(CE2,'FT')
               +QERO(CE2,'DT')**(1-erho(CE2))*PERO(CE2,'DT'));
      ae(CE2) = QEO(CE2)/
              (edel(CE2)*QERO(CE2,'FT')**(erho(CE2))
                         +(1-edel(CE2))*QERO(CE2,'DT')**(erho(CE2)))
                       **(1/erho(CE2));

      mrho(CM2) = 1/esubm(CM2) - 1;
      mdel(CM2)=(QMRO('FT',CM2)**(1+mrho(CM2)))*PMRO('FT',CM2)
           /(QMRO('FT',CM2)**(1+mrho(CM2))*PMRO('FT',CM2)
               +QMRO('DT',CM2)**(1+mrho(CM2))*PMRO('DT',CM2));
      am(CM2) = QMO(CM2)/
               (mdel(CM2)*QMRO('FT',CM2)**(-mrho(CM2))
                         +(1-mdel(CM2))*QMRO('DT',CM2)**(-mrho(CM2)))
                       **(-1/mrho(CM2));



      engelwt(H) = 1/SUM(C,(QHO(C,H)*PQO(C)*(1+(sum(HH,tc(H,C))/9)))/NYHO(H)*ine(C,H));
      ine(C,H) = engelwt(H)*ine(C,H);
      beta(C,H)=(QHO(C,H)*PQO(C)*(1+(sum(HH,tc(H,C))/9)))/NYHO(H)*ine(C,H);
      lambda(C,H)=(QHO(C,H)*PQO(C)*(1+(sum(HH,tc(H,C))/9))+beta(C,H)*NYHO(H)/frisch(C))/(PQO(C)*(1+(sum(HH,tc(H,C))/9)));
*      lambda(C,H)=0;

      cwts(C) = SUM(H,SAM(C,H))/SUM((CC,H),SAM(CC,H));
      CPIO = SUM(C,cwts(C)*PDO(C));
      shry(I,FF)   = SAM(I,FF) / (SAM('TOTAL',FF)-SUM(T,SAM(T,FF)));
      tbshr(G)  = SAM(G,'INDT')/SUM(GG,SAM(GG,'INDT'));

      sgovbal = SUM(SG,SAM('INV',SG));

Display cwts, tb, sgovbal;


VARIABLES
      PM(C)         Import price (domestic currency)
      XR(T)         Exchange rate
      PWE(C,T)      World export price
      PE(C)         Export price (domestic currency)
      PQ(C)         Composite commodity price
      PD(C)         Domestic price of domestic output
      PMR(T,C)      Regional price of imported commodities
      PER(C,T)      Regional price of exported commodities
      PA(A)         Activity price
      PVA(A)        Value added price
      PX(C)         Producer price
      QQ(C)         Quantity supplied to domestic commodity demanders
      QM(C)         Quantity of imports
      QD(C)         Quantity of domestic output sold domestically
      QMR(T,C)      Regional imports
      QER(C,T)      Regional exports
      QX(C)         Quantity of domestic output
      QE(C)         Quanitity of exports
      QA(A)         Activity level
      QF(FF,A)      Quantity demanded of factor FF by activity A
      QINT(C,A)     Quantity of intermeditate use of commodity C by activity A
      WF(FF)        Average wage or rental rate of factor FF
      YF(I,FF)      Factor income
      YH(H)         Gross household income
      NYH(H)        Net household income
      QH(C,H)       Household consumption
      QINV(C)       Investment demand
      QIINV(I)      Investment demand by institutions
      YFG           Federal government revenue
      EFG           Federal government expenditure
      YSG           State government revenue
      ESG           State government expenditure
      QFS(FF)       Factor supply
      QIBT(VA,A)    Quantity of set VA by activity A
      WALRAS        Dummy variable
      IADJ          Investment adjustment variable
      SADJ          Savings adjustment variable
      SGADJ         State government spending adjustment variable for quantity purchased
      WFDIST(FF,A)  Wage distortion factor
      INDT(G)       Total indirect taxes
      IMAKEQ(I,C)   Make matrix (quantity)
      SHIFTFF(FF)   Factor supply equation shift variable
      FSAVX         Exports foreign savings
      DSAVX         Exports RUS savings
      FSAVM         Imports foreign savings
      DSAVM         Imports RUS savings
      CPI           Consumer Price Index
;


EQUATIONS

      PMDEFF(T,C)   Regional foreign import price equation
      PEDEFF(C,T)   Regional foreign export price equation
      PMDEFD(T,C)   Regional domestic import price equation
      PEDEFD(C,T)   Regional domestic export price equation
      WEXDEM(C,T)   World export demand function
      ARMIMP(C)     Armington import composite equation
      ROWRUSM(C)    ROW-RUS import ratio
      ROWRUSE(C)    ROW-RUS export ratio
      IMPVAL(C)     Import output value
      EXPVAL(C)     Export output value
      ARMEXP(C)     Armington export composite equation
      EQMRUS(C)     Absorption equation for one imported commodity
      EQERUS(C)     Absorption equation for one exported commodity
      EPERUS(C)     Price for one exported destination
      EPMRUS(C)     Price for one imported destination
      ABSORP(C)     Absorption equation
      DOMOUT(C)     Domestic Output Value
      PADEF(A)      Activity price equation
      PVADEF(A)     Value added price
      PRODN(A)      Leontief-CES Production Functions
      FACDEM(FF,A)  Factor demand equation
      INTDEM(C,A)   Intermediate input demand equation
      IBTDEM(VA,A)  Indirect Business Tax equation
      ALLOC(C)      Output function
      ARMCOMS(C)    Armington commodity composite supply equation
      IMPDEM(C)     Import-Domestic demand ratio
      SUPNON(C)     Composite supply for nonimported commodities
      ARMCET(C)     Output transformation CET equation
      EXPDOM(C)     Export-domestic supply ratio
      OUTNON(C)     Output transformation for nonexported commodities
      FACINC(I,FF)  Factor income
      HOUSINC(H)    Household income
      NYHINCOME(H)  Net household income
      HOUSDEM(C,H)  Household consumption demand
      INVDEM(C)     Investment demand equation
      FGOVREV       Federal government revenue equation
      FGOVEXP       Federal government expenditure equation
      SGOVREV       State government revenue equation
      SGOVEXP       State government expenditure equation
      SGOVBUD       State government budget balanced
      FACMKT(FF)    Factor market equation
      COMPMKT(C)    Composite commodity market equation
      CURACCF       ROW current account balance
      CURACCD       RUS current account balance
      SAVBAL        Savings investment balance
      NORM          Price normalization equation
      INDTCALC(G)   Indirect tax calculation
      FACSUP(FF)    Factor supply equation
;


* Regional foreign import price equation
    PMDEFF('FT',CM)..
       PMR('FT',CM) =E= pwm('FT',CM)*(1+tm('FT',CM))*XR('FT');

* Regional domestic import price equation
    PMDEFD('DT',CM)..
       PMR('DT',CM) =E= pwm('DT',CM)*(1+tm('DT',CM))*XR('DT')*CPI;

* Regional foreign export price equation
    PEDEFF(CE,'FT')$QERO(CE,'FT')..
       PER(CE,'FT') =E= PWE(CE,'FT')*XR('FT')*(1-te(CE,'FT'));

* Regional foreign export price equation
    PEDEFD(CE,'DT')$QERO(CE,'DT')..
       PER(CE,'DT') =E= PWE(CE,'DT')*CPI*XR('DT')*(1-te(CE,'DT'));

* World export demand function
    WEXDEM(CE,T)..
        QER(CE,T)$QERO(CE,T) =E= xshift(CE,T)*(PWE(CE,T)**xed(CE,T));

* Armington import composite equation
    ARMIMP(CM2)..
        QM(CM2) =E=
           am(CM2)* (mdel(CM2)*QMR('FT',CM2)**(-mrho(CM2))
                   +(1-mdel(CM2))*QMR('DT',CM2)**(-mrho(CM2)))
                 **(-1/mrho(CM2));

* ROW-RUS import ratio
    ROWRUSM(CM2)..
       QMR('FT',CM2)/QMR('DT',CM2) =E=
          ((PMR('DT',CM2)/PMR('FT',CM2))*(mdel(CM2)/((1-mdel(CM2)))))**(1/(1+mrho(CM2)));

* Equilibrium for non ROW imported commodity
    EQMRUS(CM1)..
       QM(CM1) =E= QMR('DT',CM1)$QMRO('DT',CM1) + QMR('FT',CM1)$QMRO('FT',CM1);

* Price for one imported commodity
    EPMRUS(CM1)..
       PM(CM1) =E= PMR('DT',CM1)$QMRO('DT',CM1) + PMR('FT',CM1)$QMRO('FT',CM1);

* Import output value
    IMPVAL(CM2)..
        PM(CM2)*QM(CM2) =E= SUM(T,PMR(T,CM2)*QMR(T,CM2));

* Armington export composite equation
    ARMEXP(CE2)..
        QE(CE2) =E=
           ae(CE2)* (edel(CE2)*QER(CE2,'FT')**(erho(CE2))
                   +(1-edel(CE2))*QER(CE2,'DT')**(erho(CE2)))
                 **(1/erho(CE2));

* ROW-RUS export ratio
    ROWRUSE(CE2)..
       QER(CE2,'DT')/QER(CE2,'FT') =E=
          ((PER(CE2,'DT')/PER(CE2,'FT'))*(edel(CE2)/((1-edel(CE2)))))**(1/(erho(CE2)-1));

* Export output value
    EXPVAL(CE2)..
        PE(CE2)*QE(CE2) =E= SUM(T,PER(CE2,T)*QER(CE2,T));

* Quantity for one exported commodity
    EQERUS(CE1)..
       QE(CE1) =E= QER(CE1,'DT')$QERO(CE1,'DT') + QER(CE1,'FT')$QERO(CE1,'FT');

* Price for one exported commodity
    EPERUS(CE1)..
       PE(CE1) =E= PER(CE1,'DT')$QERO(CE1,'DT') + PER(CE1,'FT')$QERO(CE1,'FT');

* OLD Absorption equation
*    ABSORP(C)..
*       PQ(C)*QQ(C) =E= (1+tq(A,C))*PM(C)*QM(C)$CM(C) + (1+tq(C)+tqs(C))*PD(C)*QD(C);

* NEW Absorption equation
    ABSORP(C)..
       PQ(C)*QQ(C) =E= (1+(SUM(A,tq(A,C))/11))*PM(C)*QM(C)$CM(C) + (1+(SUM(A,tq(A,C))/11)+tqs(C))*PD(C)*QD(C);

* Domestic Output Value
    DOMOUT(C)..
       PX(C)*QX(C) =E= PD(C)*QD(C) + PE(C)*QE(C)$CE(C);

* Activity price equation
     PADEF(A)..
        PA(A) =E= SUM(C, PX(C)*theta(A,C));

* Value added price
     PVADEF(A)..
        PVA(A) =E= PA(A)*(1 - tb(A)) - SUM(C, PQ(C)*ica(C,A));

* Leontief-CES Production Functions
     PRODN(A)..
        QA(A) =E=
         (ad(A)/(1-(SAM('INDT',A))/SAM('TOTAL',A)-SUM(C, ica(C,A))))
         * (SUM(FF, del(FF,A)*QF(FF,A)**(-rho(A))))**(-1/rho(A));

* Factor demand equation
     FACDEM(FF,A)..
        WFDIST(FF,A)*WF(FF) =E=
            PVA(A) * (ad(A)/(1-tb(A)-SUM(C, ica(C,A))))
             * (SUM(FFF, del(FFF,A)*QF(FFF,A)**(-rho(A))))**((-1/rho(A))-1)
             * del(FF,A)*QF(FF,A)**(-rho(A)-1);

* Intermediate input demand equation
     INTDEM(C,A)..
        QINT(C,A) =E= ica(C,A)*QA(A);

* Indirect Business Tax equation
     IBTDEM(VA,A)..
        QIBT(VA,A) =E= ivaa(VA,A)*QA(A);

* Output function
    ALLOC(C)..
       QX(C) =E= SUM(A,theta(A,C)*QA(A)) + SUM(I,IMAKEQ(I,C));

* Armington commodity composite supply equation
    ARMCOMS(CM)..
       QQ(CM) =E=
          aq(CM)*(adel(CM)*QM(CM)**(-arho(CM))
           +(1-adel(CM))*QD(CM)**(-arho(CM)))
            **(-1/arho(CM));

* Import-Domestic demand ratio
    IMPDEM(CM)..
       QM(CM)/QD(CM) =E=
          ((adel(CM)/(1-adel(CM)))*(PD(CM)/PM(CM)))**(1/(1+arho(CM)));

* Composite supply for nonimported commodities
    SUPNON(CNM)..
       QQ(CNM) =E= QD(CNM);

* Output transformation CET equation
    ARMCET(CE)..
       QX(CE) =E=
          as(CE)* (sdel(CE)*QE(CE)**(srho(CE))+(1-sdel(CE))*QD(CE)**(srho(CE)))
                 **(1/srho(CE));

* Export-domestic supply ratio
    EXPDOM(CE)..
       QE(CE)/QD(CE) =E=
          (PE(CE)/PD(CE)*(1-sdel(CE))/sdel(CE))**(1/(srho(CE)-1));

* Output transformation for nonexported commodities
    OUTNON(CNE)..
        QX(CNE) =E= QD(CNE);

* Factor income
    FACINC(I,FF)..
        YF(I,FF) =E= shry(I,FF)*(SUM(A,WFDIST(FF,A)*QF(FF,A)*WF(FF))-CPI*SUM(T,SAM(T,FF)));

* Household income
    HOUSINC(H)..
        YH(H)
          =E= SUM(FF,YF(H,FF)) + SUM(C,PX(C)*IMAKEQ(H,C)) + CPI*SUM(G,SAM(H,G))
              + QIINV(H) + SUM(HH,trh(H,HH)*(1-SUM(G,ty(G,HH)))*YH(HH)) + CPI*SUM(T,SAM(H,T))+ trans(H);

* Net household income
   NYHINCOME(H)..
        NYH(H) =E= YH(H) - SUM(HH,trh(HH,H)*(1-SUM(G,ty(G,H)))*YH(H))
                     - SADJ*mps(H)*(1-SUM(G,ty(G,H)))*YH(H) - SUM(G,ty(G,H))*YH(H)
                    - CPI*SUM(T,SAM(T,H));

* Household consumption demand
    HOUSDEM(C,H)..
        QH(C,H) =E=
         lambda(C,H)+(beta(C,H)*(NYH(H)-SUM(CC,lambda(CC,H)*(PQ(CC)*(1+sum(HH,tc(H,C)))/9))))
         /(PQ(C)*(1+(sum(HH,tc(H,C))/9)));


* Investment demand
    INVDEM(C)..
        QINV(C) =E= IADJ*QINVO(C);

* Federal government revenue
    FGOVREV..
        YFG =E= SUM((H,FG),ty(FG,H)*YH(H)) + CPI*SUM((T,FG),SAM(FG,T))
                + SUM((C,FG),PX(C)*IMAKEQ(FG,C)) + SUM(FG,QIINV(FG))
                + CPI*SUM((FG,FGG),SAM(FG,FGG)) + SUM((FG,FF),YF(FG,FF)) + SUM(FG,INDT(FG));

* Federal government expenditures
   FGOVEXP..
        EFG =E= CPI*SUM((FG,I),SAM(I,FG)) + CPI*SUM((FG,T),SAM(T,FG)) + SUM((FG,C),PQ(C)*qg(C,FG)) - CPI*SUM(FG,SAM('INV',FG));


* NEW State government revenue (Took out "+ CPI*SUM((SG,SGG),SAM(SG,SGG))")
    SGOVREV..
        YSG =E= SUM((H,SG),ty(SG,H)*YH(H)) + CPI*SUM((T,SG),SAM(SG,T)) + CPI*SUM((SG,FG),SAM(SG,FG))
                + SUM((C,SG),PX(C)*IMAKEQ(SG,C)) + SUM(SG,QIINV(SG))
                + SUM((SG,FF),YF(SG,FF)) + SUM(SG,INDT(SG))
                + SUM(C,PD(C)*QD(C)*tqs(C))
                + SUM(C,(PM(C)*QM(C)$CM(C))*(sum(A,tq(A,C))/11)) + SUM(C,(PD(C)*QD(C))*(sum(A,tq(A,C))/11))
                + SUM((H,C),PQ(C)*QH(C,H)*tc(H,C))- sum(H,trans(H));

* State government expenditures
   SGOVEXP..
        ESG =E= CPI*(SUM((SG,I),SAM(I,SG))-SUM((SG,SGG),SAM(SGG,SG)))
                + CPI*SUM((SG,T),SAM(T,SG))+ SGADJ*SUM((SG,C),PQ(C)*qg(C,SG)) - sum(H,trans(H))- CPI*sgovbal;

* State government budget balanced
   SGOVBUD..
        YSG =E= ESG + CPI*sgovbal;

* Factor market equation
   FACMKT(FF)..
        SUM(A,QF(FF,A)) =E= QFS(FF);

* Composite commodity market equation
   COMPMKT(C)..
        QQ(C) =E= SUM(A,QINT(C,A)) + SUM(H,QH(C,H)) + SUM(FG,qg(C,FG)) + SGADJ*SUM(SG,qg(C,SG)) + QINV(C);

* ROW current account balance
   CURACCF..
        SUM(CE,PER(CE,'FT')*QER(CE,'FT')$QERO(CE,'FT')) + CPI*SUM(H,SAM(H,'FT')) + CPI*SUM(G,SAM(G,'FT')) + XR('FT')*FSAVX
               =E=
              SUM(CM,PMR('FT',CM)*QMR('FT',CM)$QMRO('FT',CM)) + CPI*SUM(FF,SAM('FT',FF)) + CPI*SUM(HG,SAM('FT',HG))
               + XR('FT')*FSAVM;

* RUS current account balance
   CURACCD..
        SUM(CE,PER(CE,'DT')*QER(CE,'DT')$QERO(CE,'DT')) + CPI*SUM(H,SAM(H,'DT')) + CPI*SUM(G,SAM(G,'DT'))
              + CPI*XR('DT')*DSAVX =E=
              SUM(CM,PMR('DT',CM)*QMR('DT',CM)$QMRO('DT',CM)) + CPI*SUM(FF,SAM('DT',FF)) + CPI*SUM(HG,SAM('DT',HG))
              + CPI*XR('DT')*DSAVM;

* Savings investment balance
    SAVBAL..
       SUM(C,PX(C)*IMAKEQ('INV',C)) + SADJ*SUM(H,mps(H)*(1-SUM(G,ty(G,H)))*YH(H)) + (YFG - EFG) + CPI*sgovbal + XR('FT')*FSAVX
             + CPI*XR('DT')*DSAVX + SUM(FF,YF('INV',FF))
           =E= SUM(C,PQ(C)*QINV(C)) + SUM(HG,QIINV(HG))
               + CPI*XR('DT')*DSAVM + XR('FT')*FSAVM + WALRAS;

* Price normalization equation
    NORM..
       SUM(C,(1+(sum(H,tc(H,C))/9))*PQ(C)*cwts(C)) =E= CPI;

* Indirect taxes calculation
     INDTCALC(G)..
        INDT(G) =E= tbshr(G)*SUM(A,tb(A)*PA(A)*QA(A));

* Factor supply equation
     FACSUP(FF)..
        QFS(FF) =E= SHIFTFF(FF)*WF(FF)**efac(FF);




OPTION MCP=PATH;

MODEL CGEMODEL
    /
    ALL
    /
;
CGEMODEL.HOLDFIXED = 1;

* Initialize the variables

      PM.L(C)       = PMO(C);
      PWE.L(C,T)    = PWEO(C,T);
      PE.L(C)       = PEO(C);
      PQ.L(C)       = PQO(C);
      PD.L(C)       = PDO(C);
      QQ.L(C)       = QQO(C);
      QM.L(C)       = QMO(C);
      QD.L(C)       = QDO(C);
      PX.L(C)       = PXO(C);
      QX.L(C)       = QXO(C);
      QE.L(C)       = QEO(C);
      PA.L(A)       = PAO(A);
      PVA.L(A)      = PVAO(A);
      QA.L(A)       = QAO(A);

      QF.L(FF,A)    = QFO(FF,A);
      QINT.L(C,A)   = QINTO(C,A);
      WF.L(FF)      = WFO(FF);
      YF.L(I,FF)    = YFO(I,FF);
      YH.L(H)       = YHO(H);
      NYH.L(H)      = NYHO(H);
      QH.L(C,H)     = QHO(C,H);
      QINV.L(C)     = QINVO(C);

      YFG.L         = YFGO;
      EFG.L         = EFGO;
      YSG.L         = YSGO;
      ESG.L         = ESGO;
      WALRAS.L      = 0;
      SGADJ.L       = SGADJO;
      INDT.L(G)     = INDTO(G);
      QMR.L(T,C)    = QMRO(T,C);
      QER.L(C,T)    = QERO(C,T);
      PMR.L(T,C)    = PMRO(T,C);
      PER.L(C,T)    = PERO(C,T);


      IMAKEQ.FX(I,C)  = IMAKEQO(I,C);
      QIINV.FX(I)     = QIINVO(I);

IF(CAPCLOS EQ 1,
*Capital is fully employed and mobile. WF('CAP') is the market-clearing
*variable for the unified capital market.

     WFDIST.FX('CAP',A) = WFDISTO('CAP',A);

     SHIFTFF.LO('CAP') = -INF;
     SHIFTFF.L('CAP') = SHIFTFFO('CAP');
     SHIFTFF.UP('CAP') = +INF;

     WF.LO('CAP')       = -INF;
     WF.UP('CAP')       = +INF;
     WF.L('CAP')        = WFO('CAP');


     QF.LO('CAP',A)     = -INF;
     QF.UP('CAP',A)     = +INF;
     QF.L('CAP',A)      = QFO('CAP',A);

     QFS.FX('CAP')       = QFSO('CAP');

);

IF(CAPCLOS EQ 2,

     WFDIST.FX('CAP',A) = WFDISTO('CAP',A);
     SHIFTFF.FX('CAP') = SHIFTFFO('CAP');

     WF.LO('CAP')       = -INF;
     WF.UP('CAP')       = +INF;
     WF.L('CAP')        = WFO('CAP');

     QF.LO('CAP',A)     = -INF;
     QF.UP('CAP',A)     = +INF;
     QF.L('CAP',A)      = QFO('CAP',A);

     QFS.LO('CAP')      = -INF;
     QFS.UP('CAP')      = +INF;
     QFS.L('CAP')       = QFSO('CAP');
);

IF(CAPCLOS EQ 3,
*Capital is fully employed and activity-specific.
*WFDIST('CAP',A) is the market-clearing variable, one for
*each segment of the capital market.

     WFDIST.LO('CAP',A) = -INF;
     WFDIST.UP('CAP',A) = +INF;
     WFDIST.L('CAP',A)  = WFDISTO('CAP',A);
     SHIFTFF.FX('CAP') = SHIFTFFO('CAP');

     WF.LO('CAP')       = -INF;
     WF.UP('CAP')       = +INF;
     WF.L('CAP')        = WFO('CAP');

     QF.FX('CAP',A)     = QFO('CAP',A);

     QFS.LO('CAP')      = -INF;
     QFS.UP('CAP')      = +INF;
     QFS.L('CAP')       = QFSO('CAP');
);

IF(LABCLOS EQ 1,
*Labor is fully employed and mobile. WF('LAB') is the market-clearing
*variable for the unified capital market.

     WFDIST.FX('LAB',A) = WFDISTO('LAB',A);

     SHIFTFF.LO('LAB') = -INF;
     SHIFTFF.UP('LAB') = +INF;
     SHIFTFF.L('LAB') = SHIFTFFO('LAB');

     WF.LO('LAB')       = -INF;
     WF.UP('LAB')       = +INF;
     WF.L('LAB')        = WFO('LAB');

     QF.LO('LAB',A)     = -INF;
     QF.UP('LAB',A)     = +INF;
     QF.L('LAB',A)      = QFO('LAB',A);

     QFS.FX('LAB')       = QFSO('LAB');
);

IF(LABCLOS EQ 2,
*Labor is fully employed and mobile. WF('LAB') is the market-clearing
*variable for the unified capital market.

     WFDIST.FX('LAB',A) = WFDISTO('LAB',A);
     SHIFTFF.FX('LAB') = SHIFTFFO('LAB');

     WF.LO('LAB')       = -INF;
     WF.UP('LAB')       = +INF;
     WF.L('LAB')        = WFO('LAB');

     QF.LO('LAB',A)     = -INF;
     QF.UP('LAB',A)     = +INF;
     QF.L('LAB',A)      = QFO('LAB',A);

     QFS.LO('LAB')      = -INF;
     QFS.UP('LAB')      = +INF;
     QFS.L('LAB')       = QFSO('LAB');
);

IF(LABCLOS EQ 3,
*Labor is unemployed and mobile. For each activity, the wage,
*WFDIST('LAB',A)*WF('LAB'), is fixed. QFS('LAB') is the market-clearing
*variable for the unified labor market.

     WFDIST.FX('LAB',A) = WFDISTO('LAB',A);

     SHIFTFF.LO('LAB') = -INF;
     SHIFTFF.UP('LAB') = +INF;
     SHIFTFF.L('LAB') = SHIFTFFO('LAB');

     WF.FX('LAB')       = WFO('LAB');

     QF.LO('LAB',A)     = -INF;
     QF.UP('LAB',A)     = +INF;
     QF.L('LAB',A)      = QFO('LAB',A);

     QFS.LO('LAB')      = -INF;
     QFS.UP('LAB')      = +INF;
     QFS.L('LAB')       = QFSO('LAB');
);

*SAVINGS-INVESTMENT BALANCE

IF(SICLOS EQ 1,
*Investment-driven savings -- MPS('U-HHD') is flexible, permitting
*the savings value to adjust.
     IADJ.FX     = IADJO;
     CPI.FX      = CPIO;
     SADJ.LO     = -INF;
     SADJ.UP     = +INF;
     SADJ.L      = SADJO;
 );

IF(SICLOS EQ 2,
*Savings-driven investment -- IADJ is flexible, permitting
*investment quantities and the investment value to adjust.
     SADJ.FX   = SADJO;
     CPI.FX    = CPIO;
     IADJ.LO   = -INF;
     IADJ.UP   = +INF;
     IADJ.L    = IADJO;
 );

IF(SICLOS EQ 3,
* Savings and investment are not linked.
* All investment except federal govt is fixed.
* Federal govt investment adjusts.
     SADJ.FX    = SADJO;
     IADJ.FX    = IADJO;
     CPI.LO     = -INF;
     CPI.UP     = +INF;
     CPI.L      = CPIO;
 );

*THE FOREIGN EXCHANGE MARKET

IF(ROWCLOS EQ 1,
*Foreign savings is fixed. A flexible exchange rate clears
*the current account of the balance of payments.
       FSAVX.FX = FSAVXO;
       FSAVM.FX = FSAVMO;
       XR.LO('FT')  = -INF;
       XR.UP('FT')  = +INF;
       XR.L('FT')   = XRO('FT');
 );

IF(ROWCLOS EQ 2,
*The exchange rate is fixed. Flexible foreign savings clears
*the current account of the balance of payments.
      XR.FX('FT')   = XRO('FT');
      FSAVM.FX = FSAVMO;
      FSAVX.LO  = -INF;
      FSAVX.UP  = +INF;
      FSAVX.L   = FSAVXO;
 );

IF(ROWCLOS EQ 3,
*The exchange rate is fixed. Flexible foreign savings clears
*the current account of the balance of payments.
      XR.FX('FT')   = XRO('FT');
      FSAVX.FX = FSAVXO;
      FSAVM.LO  = -INF;
      FSAVM.UP  = +INF;
      FSAVM.L   = FSAVMO;
 );

*THE RUS EXCHANGE MARKET

IF(RUSCLOS EQ 1,
*Foreign savings is fixed. A flexible RUS exchange rate clears
*the current account of the balance of payments.
       DSAVM.FX = DSAVMO;
       DSAVX.FX = DSAVXO;
       XR.LO('DT')  = -INF;
       XR.UP('DT')  = +INF;
       XR.L('DT')   = XRO('DT');
 );

IF(RUSCLOS EQ 2,
*The exchange rate is fixed. Flex RUS savings clears
*the current account of the balance of payments.
      XR.FX('DT')   = XRO('DT');
      DSAVM.FX = DSAVMO;
      DSAVX.LO  = -INF;
      DSAVX.UP  = +INF;
      DSAVX.L   = DSAVXO;
 );

IF(RUSCLOS EQ 3,
*The exchange rate is fixed. Flex RUS savings clears
*the current account of the balance of payments.
      XR.FX('DT')   = XRO('DT');
      DSAVX.FX = DSAVXO;
      DSAVM.LO  = -INF;
      DSAVM.UP  = +INF;
      DSAVM.L   = DSAVMO;
 );



* Set counterfactual

* YEAR 1 SCENARIOS

* (Itteration 2) this counterfactual reduces the IBT for manufactoring
*tb('MAN-A') = .00158;
*tb('FOOD-A') = .01403;

* (Itteration 1)this counterfactual is a 0.5% reduction in the sales tax paid by all sectors
*tc(H,NSER) = -.005;
*tc(H,'SER-C') = -.0015;


* (Itteration 3) this counterfactual addes a comodity fuel tax
*tq(NAG,'FOSSIL-C')= .04561;
*tq('AGR-A','FOSSIL-C')= .0019;

*(Itteration 4) This is how we built in the low income carbon transfer payment
*trans('HHD1')= 157.74



* YEAR 2 SCENARIOS
* (Itteration 2) this counterfactual reduces the IBT for manufactoring * (Itteration 1)this counterfactual is a 1% reduction in the sales tax paid by all sectors
tb('MAN-A') = .00158;
tb('FOOD-A') = .01403;

* (Itteration 1)this counterfactual is a 1% reduction in the sales tax paid by all sectors
tc(H,NSER) = -.01;
tc(H,'SER-C') = -.003;

* (Itteration 3) this counterfactual addes a comodity fuel tax
tq(NAG,'FOSSIL-C')= .076;
tq('AGR-A','FOSSIL-C')= .0038;

*(Itteration 4)This is how we built in the low income carbon transfer payment
trans('HHD1')= 262.899



SOLVE CGEMODEL USING MCP;



PARAMETERS
         UTO(H)       Base household utility
         UT(H)        Household Utility
         EV(H)        Equivalent Variation
         IMPORTSO(T)  Base imports
         IMPORTS(T)   Counterfactual imports
         EXPORTSO(T)  Base exports
         EXPORTS(T)   Counterfactual exports
         GDPFCO       Base total wage and capital bill (GDP at factor cost)--  all the following based on Kendrick notes
         GDPFC        Counterfactual wage and capital bill (GDP at factor cost)-- Kendrick notes
         GDPMCO1      Base state  GDP (c + i + g + e - m)  (GDP at market prices--Kendrick notes
         GDPMC1       Counterfactual  state  GDP (c + i + g + e - m) (GDP at market prices--Kendrick notes
         GDPMCO2      Base value added for economy (wage and capital bill plus indirect business taxes)--also = GDP at market prices?
         GDPMC2       Counterfactual value added for economy (wage and capital bill plus indirect business taxes) --also = GDP at market prices
         GDPMCO3      Total activity output minus intermediate cost minus (ibt) equals total wage and capital bill
         GDPMC3       Counterfactual Total activity output minus intermediate cost minus (ibt) equals total wage and capital bill
*State Revenue equations
      YSG1          Houshold Income tax Revenue
      YSG2          Tarifs
      YSG3          Federal payments to States
      YSG4          Government enterprise revenue
      YSG5          State investments
      YSG6          Factor income
      YSG7          Industry payments
      YSG8          Sales tax revenue (Imports)
      YSG9          Sales tax revenue (Domestic)
      YSG10         Consumtion tax revenue
      YSG11         Service tax revenue
      YSG12         Total State Government

      ESG1            government institution
      ESG2            government trade
      ESG3            government consumption
      ESG4            government low income transfer
      ESG5            Agr
      ESG6            Const
      ESG7            Util
      ESG8            Fossil
      ESG9            Trad
      ESG10           Min
      ESG11           Food
      ESG12           Man
      ESG13           Serv
      ESG14           Misc

*sales tax by sector
      YSG8AGR          Agr tax revenue
      YSG8FOREST       Forestry  tax revenue
      YSG8CONST        Construction  tax revenue
      YSG8UTIL         Utilities tax revenue
      YSG8Fossil       Fossil-Fuel tax revenue
      YSG8TRAD         Wholesale and retail trade tax revenue
      YSG8MIN          Mining and quarrying  tax revenue
      YSG8FOOD         Processed food  tax revenue
      YSG8MAN          Manufacturing tax revenue
      YSG8SER          Services  tax revenue
      YSG8MISC         Miscellaneous tax revenue
      YSG8TOTAL        Should match YSG8

;

* Calculate some descriptive parameters based upon the output of the model

UTO(H) = SUM(C,beta(C,H)*LOG(QHO(C,H)-lambda(C,H))$(QHO(C,H)-lambda(C,H) GT 0));
UT(H) = SUM(C,beta(C,H)*LOG(QH.L(C,H)-lambda(C,H))$(QH.L(C,H)-lambda(C,H) GT 0));
EV(H) = (NYH.L(H) - SUM(C,lambda(C,H)*PQ.L(C)*(1+(sum(HH,tc(H,C))/9))))*PROD(C,(PQO(C)/(PQ.L(C)*1+(sum(HH,tc(H,C))/9)))**beta(C,H))
         - (NYHO(H) - SUM(C,lambda(C,H)*PQO(C)));
IMPORTSO(T) = SUM(C,QMRO(T,C));
IMPORTS(T) = SUM(C,QMR.L(T,C));
EXPORTSO(T) = SUM(C,QERO(C,T));
EXPORTS(T) = SUM(C,QER.L(C,T));
GDPFCO = SUM(FF,SAM(FF,'TOTAL'));
GDPFC = SUM((FF,A),QF.L(FF,A)*WFDIST.L(FF,A)*WF.L(FF));
GDPMCO2 = SUM(F,SAM(F,'TOTAL'));
GDPMC2 = GDPFC + SUM(A,tb(A)*PA.L(A)*QA.L(A));
GDPMCO1 = SUM((C,I),SAM(C,I)) + SUM((C,T),SAM(C,T)) - SUM((T,C),SAM(T,C));
GDPMC1 = SUM((C,HH),PQ.L(C)*QH.L(C,HH)) + SUM((C,G),PQ.L(C)*qg(C,G))
         + SUM(C,PQ.L(C)*QINV.L(C)) + SUM((C,T),PER.L(C,T)*QER.L(C,T))
         - SUM((T,C),PMR.L(T,C)*QMR.L(T,C));

GDPMCO3 = SUM(A,SAM(A,'TOTAL')) - SAM('INDT','TOTAL') - SUM((C,A),SAM(C,A));
GDPMC3 = SUM((C,A),theta(A,C)*PX.L(C)*QA.L(A)) - SUM(A,tb(A)*PA.L(A)*QA.L(A)) - SUM((C,A),PQ.L(C)*QINT.L(C,A));

* Income Tax Revenue
        YSG1 = SUM((H,SG),ty(SG,H)*YH.L(H));
* Tarifs
        YSG2 = CPI.L*SUM((T,SG),SAM(SG,T));
* Federal Transfers to States
        YSG3 = CPI.L*SUM((SG,FG),SAM(SG,FG));
* State Enterprise Revenue
        YSG4 = SUM((C,SG),PX.L(C)*IMAKEQ.L(SG,C));
* State Investment
        YSG5 = SUM(SG,QIINV.L(SG));
* Factor Income
        YSG6 = SUM((SG,FF),YF.L(SG,FF));
* Industry Payments
        YSG7 = SUM(SG,INDT.L(SG));
* Sales Tax Revenue (Imports)
        YSG8 = SUM(C,(PM.L(C)*QM.L(C)$CM(C)*(sum(A,tq(A,C))/11)));
* Sales Tax Revenue (Domestic)
        YSG9 = SUM(C,(PD.L(C)*QD.L(C)*(sum(A,tq(A,C))/11)));
* Consumption Tax Revenue
        YSG10 = SUM((H,C),PQ.L(C)*tc(H,C)*QH.L(C,H));
* Service Tax Revenue
        YSG11 = SUM(C,PD.L(C)*QD.L(C)*tqs(C));

        YSG12 =  YSG.L-YSGO;
* YSG1, YSG2, YSG3, YSG4, YSG5, YSG6, YSG7, YSG8, YSG9, YSG10,
Display   YSG1, YSG2, YSG3, YSG4, YSG5, YSG6, YSG7, YSG8, YSG9, YSG10, YSG11, YSG12;

* State government expenditures
*government institutions
*ESG1 = CPI.L*(SUM((SG,I),SAM(I,SG))-SUM((SG,SGG),SAM(SGG,SG)));
*Government trade
*ESG2 = CPI.L*SUM((SG,T),SAM(T,SG));
*Government consumption
*ESG3 = SGADJ.L*SUM((SG,C),PQ.L(C)*qg(C,SG));
*Government low income payment
*ESG4 = sum(H,trans(H));
* government budget balance variable
*ESG5 = SGADJ.L*sum(SG,qg('AGR-C',SG));
*ESG6 = SGADJ.L*sum(SG,qg('CONST-C',SG));
*ESG7 = SGADJ.L*sum(SG,qg('UTIL-C',SG));
*ESG8 = SGADJ.L*sum(SG,qg('FOSSIL-C',SG));
*ESG9 = SGADJ.L*sum(SG,qg('TRAD-C',SG));
*ESG10 = SGADJ.L*sum(SG,qg('MIN-C',SG));
*ESG11 = SGADJ.L*sum(SG,qg('FOOD-C',SG));
*ESG12 = SGADJ.L*sum(SG,qg('MAN-C',SG));
*ESG13 = SGADJ.L*sum(SG,qg('SER-C',SG));
*ESG14 = SGADJ.L*sum(SG,qg('MISC-C',SG));

*Display ESG1, ESG2, ESG3, ESG4, ESG5, ESG6, ESG7, ESG8, ESG9, ESG10, ESG11, ESG12, ESG13, ESG14;

* Call the report generator (User should change the filename)

$BATINCLUDE "%PROGPATH%REPORT.GMS"  Model6.SPODE